【Excel】excel同列单元格，前后相同内容批量合并居中

excel同列单元格，前后相同内容合并居中

就是将一列单元格的内容进行合并居中操作，如下图：

变成为：

直接上操作：本次以Excel宏代码进行

一、窗口——Visual Basic

二、打开 VBA 编辑器——插入模块——粘贴代码——保存。

代码如下：

Sub MergeIdenticalAdjacentCells()
    Dim rng As Range
    Dim cell As Range
    Dim startRow As Long
    Dim endRow As Long
    Dim col As Long
    Dim i As Long
    
    On Error GoTo ErrorHandler
    Set rng = Selection
    If rng.Columns.Count > 1 Then
        MsgBox "请只选中一列数据", vbExclamation
        Exit Sub
    End If
    
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
    
    col = rng.Column
    startRow = rng.Row
    endRow = startRow + rng.Rows.Count - 1
    
    i = startRow
    Do While i <= endRow
        Dim j As Long
        j = i
        Do While j < endRow And Cells(j, col).Value = Cells(j + 1, col).Value
            j = j + 1
        Loop
        
        If j > i Then
            Range(Cells(i, col), Cells(j, col)).Merge
        End If
        
        i = j + 1
    Loop
    
    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
    MsgBox "合并完成"
    Exit Sub
    
ErrorHandler:
    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
    MsgBox "出错：" & Err.Description
End Sub

三、回到 Excel，选中您要处理的那一列数据区域（不要整列，不要整列，不要整列，选择整列会将后面空白的一起执行，会很慢）

四、按 Alt+F8 ——选择 MergeIdenticalAdjacentCells ——运行，完成。

===================内容扩展（相反操作）===================

【EXCEL】excel隔行快速批量复制粘贴,去掉合并居中